96 lines
3.0 KiB
GLSL
96 lines
3.0 KiB
GLSL
#version 130
|
|
// Fisheye removal for GoPro 11+, 8:7 ratio, without hypersmooth
|
|
// Copyright (C) 2025 Jean-Baptiste Berlioz
|
|
//
|
|
// This program is free software: you can redistribute it and/or modify
|
|
// it under the terms of the GNU Affero General Public License as
|
|
// published by the Free Software Foundation, either version 3 of the
|
|
// License, or (at your option) any later version.
|
|
//
|
|
// This program is distributed in the hope that it will be useful,
|
|
// but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
// GNU Affero General Public License for more details.
|
|
//
|
|
// You should have received a copy of the GNU Affero General Public License
|
|
// along with this program. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
#extension GL_ARB_texture_rectangle: enable
|
|
|
|
#define rotate_180
|
|
//#define debug_borders
|
|
|
|
#undef highp // defined by Qt-OpenGl
|
|
precision highp float;
|
|
|
|
// uniforms
|
|
uniform sampler2DRect myTextureY;
|
|
uniform sampler2DRect myTextureU;
|
|
uniform sampler2DRect myTextureV;
|
|
uniform vec2 myResolution;
|
|
uniform float pts;
|
|
|
|
// parameters
|
|
const vec2 sensor_size = vec2(5.949440, 5.205760);
|
|
const float equidistant_focal_length = 3.020000;
|
|
const float rectilinear_focal_length = 2.232346;
|
|
|
|
// constants
|
|
const int subsampling = 4;
|
|
const vec2 subsampling_step = vec2(1.0 / float(subsampling));
|
|
const vec2 subsampling_start = subsampling_step * 0.5 - vec2(0.5);
|
|
const float subsampling_scale = 1.0 / float(subsampling * subsampling);
|
|
|
|
// variables
|
|
vec2 texture_center;
|
|
vec2 texture_to_sensor;
|
|
vec2 sensor_to_texture;
|
|
|
|
void initialize() {
|
|
texture_center = myResolution * 0.5;
|
|
texture_to_sensor = sensor_size / myResolution;
|
|
#ifdef rotate_180
|
|
texture_to_sensor *= -1.0;
|
|
#endif
|
|
sensor_to_texture = myResolution / sensor_size;
|
|
}
|
|
|
|
vec2 equidistant_to_rectilinear(const in vec2 coord) {
|
|
float rectilinear_radius = length(coord);
|
|
float rectilinear_angle = atan(rectilinear_radius / rectilinear_focal_length);
|
|
float equidistant_radius = rectilinear_angle * equidistant_focal_length;
|
|
return coord * (equidistant_radius / rectilinear_radius);
|
|
}
|
|
|
|
vec4 sample_texture(const in vec2 coord) {
|
|
vec2 rectilinear = equidistant_to_rectilinear((coord - texture_center) * texture_to_sensor);
|
|
vec2 y_coord = texture_center + rectilinear * sensor_to_texture;
|
|
#ifdef debug_borders
|
|
if (y_coord.x < 0.0 || y_coord.y < 0.0 || y_coord.x > myResolution.x || y_coord.y > myResolution.y) {
|
|
return vec4(1.0);
|
|
}
|
|
#endif
|
|
vec2 uv_coord = y_coord * 0.5;
|
|
return vec4(
|
|
texture2DRect(myTextureY, y_coord).x,
|
|
texture2DRect(myTextureU, uv_coord).x,
|
|
texture2DRect(myTextureV, uv_coord).x,
|
|
1.0);
|
|
}
|
|
|
|
void main() {
|
|
initialize();
|
|
|
|
vec2 coord = gl_TexCoord[0].xy;
|
|
vec4 pixel = vec4(0.0);
|
|
|
|
for (int y = 0; y < subsampling; y++) {
|
|
for (int x = 0; x < subsampling; x++) {
|
|
vec2 offset = subsampling_start + subsampling_step * vec2(x, y);
|
|
pixel += sample_texture(coord + offset);
|
|
}
|
|
}
|
|
|
|
gl_FragColor = pixel * subsampling_scale;
|
|
}
|