89 lines
2.4 KiB
GLSL
89 lines
2.4 KiB
GLSL
#version 130
|
|
// RozK
|
|
// Fisheye removal for GoPro 11+, 8:7 ratio, without hypersmooth
|
|
|
|
#extension GL_ARB_texture_rectangle: enable
|
|
|
|
#undef highp // defined by Qt-OpenGl
|
|
#define rotate_180
|
|
//#define debug_borders
|
|
|
|
precision highp float;
|
|
|
|
// uniforms
|
|
uniform sampler2DRect myTextureY;
|
|
uniform sampler2DRect myTextureU;
|
|
uniform sampler2DRect myTextureV;
|
|
uniform vec2 myResolution;
|
|
uniform float pts;
|
|
|
|
// parameters
|
|
const vec2 sensor_size = vec2(5.949440, 5.205760);
|
|
const vec2 pixel_scale = vec2(0.871558, 1.0);
|
|
const float equidistant_focal_length = 2.920000;
|
|
const float rectilinear_focal_length = 2.102263;
|
|
|
|
// constants
|
|
const int subsampling = 4;
|
|
const vec2 subsampling_step = vec2(1.0 / float(subsampling));
|
|
const vec2 subsampling_start = subsampling_step * 0.5 - vec2(0.5);
|
|
const float subsampling_scale = 1.0 / float(subsampling * subsampling);
|
|
|
|
// variables
|
|
vec2 texture_center;
|
|
vec2 texture_to_sensor;
|
|
vec2 sensor_to_texture;
|
|
|
|
void initialize() {
|
|
texture_center = myResolution * 0.5;
|
|
texture_to_sensor = (sensor_size / myResolution) * pixel_scale;
|
|
#ifdef rotate_180
|
|
texture_to_sensor *= -1.0;
|
|
#endif
|
|
sensor_to_texture = (myResolution / sensor_size);
|
|
}
|
|
|
|
vec2 unfish_coord(const in vec2 coord) {
|
|
float rectilinear_radius = length(coord);
|
|
float rectilinear_angle = atan(rectilinear_radius / rectilinear_focal_length);
|
|
float equidistant_radius = rectilinear_angle * equidistant_focal_length;
|
|
return coord * (equidistant_radius / rectilinear_radius);
|
|
}
|
|
|
|
vec4 unfish_pixel(const in vec2 coord) {
|
|
vec2 unfished = unfish_coord((coord - texture_center) * texture_to_sensor);
|
|
vec2 y_coord = texture_center + unfished * sensor_to_texture;
|
|
|
|
// y_coord.y = coord.y;
|
|
|
|
#ifdef debug_borders
|
|
if (y_coord.x < 0.0 || y_coord.y < 0.0 || y_coord.x > myResolution.x || y_coord.y > myResolution.y) {
|
|
return vec4(1.0);
|
|
}
|
|
#endif
|
|
|
|
vec2 uv_coord = y_coord * 0.5;
|
|
return vec4(
|
|
texture2DRect(myTextureY, y_coord).r,
|
|
texture2DRect(myTextureU, uv_coord).r,
|
|
texture2DRect(myTextureV, uv_coord).r,
|
|
1.0
|
|
);
|
|
}
|
|
|
|
void main() {
|
|
initialize();
|
|
|
|
vec2 coord = gl_TexCoord[0].xy;
|
|
vec4 pixel = vec4(0.0);
|
|
|
|
for (int y = 0; y < subsampling; y++) {
|
|
for (int x = 0; x < subsampling; x++) {
|
|
vec2 offset = subsampling_start + subsampling_step * vec2(x, y);
|
|
pixel += unfish_pixel(coord + offset);
|
|
}
|
|
}
|
|
|
|
gl_FragColor = pixel * subsampling_scale;
|
|
}
|