126 lines
4.1 KiB
GLSL
126 lines
4.1 KiB
GLSL
#version 130
|
|
// Fisheye removal for GoPro 11+, 8:7 ratio, without hypersmooth
|
|
// Copyright (C) 2025 Jean-Baptiste Berlioz
|
|
//
|
|
// This program is free software: you can redistribute it and/or modify
|
|
// it under the terms of the GNU Affero General Public License as
|
|
// published by the Free Software Foundation, either version 3 of the
|
|
// License, or (at your option) any later version.
|
|
//
|
|
// This program is distributed in the hope that it will be useful,
|
|
// but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
// GNU Affero General Public License for more details.
|
|
//
|
|
// You should have received a copy of the GNU Affero General Public License
|
|
// along with this program. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
#extension GL_ARB_texture_rectangle: enable
|
|
|
|
#define non_linear_decoding
|
|
#define rotate_180
|
|
//#define debug_borders
|
|
|
|
#undef highp // defined by Qt-OpenGl
|
|
precision highp float;
|
|
|
|
// uniforms
|
|
uniform sampler2DRect myTextureY;
|
|
uniform sampler2DRect myTextureU;
|
|
uniform sampler2DRect myTextureV;
|
|
uniform vec2 myResolution;
|
|
uniform float pts;
|
|
|
|
// parameters
|
|
const vec2 sensor_size = vec2(5.949440, 5.205760);
|
|
const float equidistant_focal_length = 2.970000;
|
|
const float rectilinear_focal_length = 2.167601;
|
|
|
|
// constants
|
|
const int subsampling = 4;
|
|
const vec2 subsampling_step = vec2(1.0 / float(subsampling));
|
|
const vec2 subsampling_start = subsampling_step * 0.5 - vec2(0.5);
|
|
const float subsampling_scale = 1.0 / float(subsampling * subsampling);
|
|
|
|
// variables
|
|
vec2 texture_center;
|
|
vec2 texture_to_sensor;
|
|
vec2 sensor_to_texture;
|
|
|
|
void initialize() {
|
|
texture_center = myResolution * 0.5;
|
|
texture_to_sensor = sensor_size / myResolution;
|
|
#ifdef rotate_180
|
|
texture_to_sensor *= -1.0;
|
|
#endif
|
|
sensor_to_texture = myResolution / sensor_size;
|
|
}
|
|
|
|
vec2 equidistant_to_rectilinear(const in vec2 coord) {
|
|
float rectilinear_radius = length(coord);
|
|
float rectilinear_angle = atan(rectilinear_radius / rectilinear_focal_length);
|
|
float equidistant_radius = rectilinear_angle * equidistant_focal_length;
|
|
return coord * (equidistant_radius / rectilinear_radius);
|
|
}
|
|
|
|
vec3 sample_texture(const in vec2 coord) {
|
|
vec2 rectilinear = equidistant_to_rectilinear((coord - texture_center) * texture_to_sensor);
|
|
vec2 y_coord = texture_center + rectilinear * sensor_to_texture;
|
|
#ifdef debug_borders
|
|
if (y_coord.x < 0.0 || y_coord.y < 0.0 || y_coord.x > myResolution.x || y_coord.y > myResolution.y) {
|
|
return vec3(16.0 / 255.0, 0.5, 0.5);
|
|
}
|
|
#endif
|
|
vec2 uv_coord = y_coord * 0.5;
|
|
return vec3(
|
|
texture2DRect(myTextureY, y_coord).x,
|
|
texture2DRect(myTextureU, uv_coord).x,
|
|
texture2DRect(myTextureV, uv_coord).x);
|
|
}
|
|
|
|
#ifdef non_linear_decoding
|
|
|
|
// https://en.wikipedia.org/wiki/Rec._709
|
|
|
|
#define y_min ( 16.0 / 255.0)
|
|
#define y_max (235.0 / 255.0)
|
|
#define uv_min ( 16.0 / 255.0)
|
|
#define uv_max (240.0 / 255.0)
|
|
#define y_range (y_max - y_min)
|
|
#define uv_range (uv_max - uv_min)
|
|
|
|
const vec3 yuv_min = vec3(y_min, uv_min, uv_min);
|
|
const vec3 yuv_range = vec3(y_range, uv_range, uv_range);
|
|
const vec3 yuv_center = vec3(0.0, 0.5, 0.5);
|
|
|
|
vec3 decode_pixel(const in vec3 pixel) {
|
|
vec3 color = (pixel - yuv_min) / yuv_range - yuv_center;
|
|
float l = (color.x < 0.081) ? (color.x / 4.5) : pow((color.x + 0.099) / 1.099, 1.0 / 0.45);
|
|
return vec3(l, color.yz);
|
|
}
|
|
|
|
vec3 encode_color(const in vec3 color) {
|
|
float y = (color.x < 0.018) ? (color.x * 4.5) : (pow(color.x, 0.45) * 1.099 - 0.099);
|
|
return (vec3(y, color.yz) + yuv_center) * yuv_range + yuv_min;
|
|
}
|
|
|
|
#else
|
|
|
|
#define decode_pixel(_pixel) _pixel
|
|
#define encode_color(_color) _color
|
|
|
|
#endif // non_linear_decoding
|
|
|
|
void main() {
|
|
initialize();
|
|
vec2 coord = gl_TexCoord[0].xy;
|
|
vec3 color = vec3(0.0);
|
|
for (int y = 0; y < subsampling; y++) {
|
|
for (int x = 0; x < subsampling; x++) {
|
|
vec2 offset = subsampling_start + subsampling_step * vec2(x, y);
|
|
color += decode_pixel(sample_texture(coord + offset));
|
|
}
|
|
}
|
|
gl_FragColor = vec4(encode_color(color * subsampling_scale), 1.0);
|
|
}
|