// Copyright (C) 2022 RozK
//
// This program is free software: you can redistribute it and/or modify
// it under the terms of the GNU Affero General Public License as published by
// the Free Software Foundation, either version 3 of the License, or
// (at your option) any later version.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
// GNU Affero General Public License for more details.
//
// You should have received a copy of the GNU Affero General Public License
// along with this program.  If not, see <http://www.gnu.org/licenses/>.

#version 320 es
precision highp float;

layout(location = 0) in vec3 a_position; // model space
layout(location = 1) in vec3 a_normal; // model space
layout(location = 2) in vec3 a_texcoord; // texture space

layout(location = 3) in vec3 i_translation; // per mesh, model space -> world space
layout(location = 4) in vec3 i_orientation; // per mesh, model space -> world space

uniform mat4 u_view; // world space -> view space
uniform mat4 u_projection; // view space -> screen space

uniform highp sampler2D u_height_sampler;
uniform highp sampler2D u_normal_sampler;

const vec3 c_normal_scale = vec3(2.0, 2.0, 1.0);
const vec3 c_normal_shift = vec3(-1.0, -1.0, 0.0);
const vec2 c_st_scale = vec2(1.0 / 1023.0, 1.0 / 1023.0);
const vec2 c_terrain_scale = vec2(1.0 / 2048.0, -1.0 / 2048.0);
const vec2 c_terrain_shift = vec2(0.5, 0.5);
const float c_weight_scale = 1.0 / 64.f;
const vec3 c_world_forward = vec3(0.0, 1.0, 0.0);
const vec3 c_world_up = vec3(0.0, 0.0, 1.0);

out vec4 v_position; // view space
out vec4 v_normal; // view space
out vec4 v_terrain_normal; // view space (x, y, z, weigth)
out vec4 v_texcoord; // texture space (s, t, pixel_level, material_level)

void main(void) {
    vec3 orientation = normalize(i_orientation);
    mat3 rotation = mat3(cross(orientation, c_world_up), orientation, c_world_up);
    vec4 world_position = vec4(i_translation + rotation * a_position, 1.0);
    float weight = max(0.0, 1.0 - world_position.z * c_weight_scale);
    vec3 world_normal = rotation * normalize(a_normal);
    vec2 terrain_coords = c_terrain_shift + world_position.xy * c_terrain_scale;
    world_position.z += texture(u_height_sampler, terrain_coords).r;
    vec4 view_position = u_view * world_position;
    vec3 terrain_normal = normalize(c_normal_shift + texture(u_normal_sampler, terrain_coords).rgb * c_normal_scale);
    world_normal = mat3(cross(c_world_forward, terrain_normal), c_world_forward, terrain_normal) * world_normal;
    v_position = view_position;
    v_normal = u_view * vec4(world_normal, 0.0);
    v_terrain_normal = vec4((u_view * vec4(terrain_normal, 0.0)).xyz, weight);
    v_texcoord = vec4(a_texcoord.st * c_st_scale, a_texcoord.p, a_texcoord.p + 1.0);
    gl_Position = u_projection * view_position;
}
